Dynamic Pie Chart in Flash 5 - Page 7

Adding the Actions

Step 4 : Understanding and Building the Code

The entire code is shown below. If you're creating this movie yourself, you can cut and paste the code from this page into the Frame Actions tab for frame 1 of the movie. In the proceeding pages, I've broken the code to show what's happening.

aCount = new Array(20, 5, 50, 37, 10);
aCategory = new Array("lions", "monkeys", "birds", "elephants", "snakes");
nElements = aCount.length;
aColor = new Array(0x0000cc, 0x669999, 0xcc66cc, 0x00cccc, 0x9933cc);
aPercent = new Array(nElements);
nDepth = 1;
// Calculate total
for (i=0; i < nElements; i++) {
	nTotal += aCount[i];
}
// Calculate percents
for (i=0; i < nElements; i++) {
	aPercent[i] = math.round((aCount[i]/nTotal)*100);
	nTotalPercent += aPercent[i];  // keep for later fix
	if (i < nElements-1) {
		nAllButLast += aPercent[i];	   // keep this for later fix too
	}
}
// if percents don't add to 100 (because of rounding they can be off by 1), fix last percent
if (nTotalPercent != 100) {
	aPercent[nElements-1] = 100 - nAllButLast;
}
// trace(aCount + " " + nTotal + " " + aPercent + " " + nTotalPercent + " " + nAllButLast);
// subtract 1 from first percent because 1 pie slice exists already
aPercent[0] -= 1;

nRunningSum = 0;
for (i=0; i < nElements; i++) {
    // duplicate key symbol and set to correct color
    mcKey.duplicateMovieClip ("mcKey"+i, nDepth++);
    _root["mcKey"+i]._x = 300;
    _root["mcKey"+i]._y = i*30+60;
    tempColor = new Color(eval("mcKey" + i));
    tempColor.setRGB(aColor[i]);
    // attach category text movieclip and set to correct category
    _root.attachMovie ("mcCategory", "mcCategory"+i, nDepth++);
    _root["mcCategory"+i].tfCategory = aCategory[i];
    _root["mcCategory"+i]._x = 330;
    _root["mcCategory"+i]._y = i*30+60;
    // duplicate slice until percent is complete, set color
    for (j=0; j < aPercent[i]; j++) {
        mcPie.duplicateMovieClip ("mcPie"+i*nElements+j, nDepth++);
        _root["mcPie"+i*nElements+j]._rotation = nRunningSum - 3.6;
        nRunningSum -= 3.6;
        tempColor = new Color(eval("mcPie" + i*nElements+j));
        tempColor.setRGB(aColor[i]);
	}
    // nDepth is separate from i because it's used for key symbol and text too
}
stop ();