Flash Clock with the server's time using PHP - Page 4

You can get a better looking result by adding leading zeros to some of the values.
This can be seen in the much simpler example where the time displayed comes from the computer - MainComputer.as:

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.text.TextField;

	public class MainComputer extends Sprite 
	{
		
		public var text_txt:TextField;		
		
		
		public function MainComputer():void 
		{
			// make sure the stage property exists
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
		
		/**
		 * load the data from the php script
		 * @param	e
		 */
		private function init(e:Event = null):void 
		{
			// make sure the text field has no text
			text_txt.text = "";
			
			// start a repetitive task
			addEventListener(Event.ENTER_FRAME, updateClock);
		}

		/**
		 * show the updated time and date
		 * @param	e
		 */
		private function updateClock(e:Event):void 
		{
			var myDate:Date = new Date();
			
			// get the seconds, minutes and hours
			var seconds:uint = myDate.getSeconds();
			var minutes:uint = myDate.getMinutes();
			var hours:uint = myDate.getHours();
			
			// get the year, month and day
			var year:uint = myDate.getFullYear();
			var month:uint = myDate.getMonth() + 1;
			var day:uint = myDate.getDate();
			
			// add leading zeros to all that may require for a better looking result
			var seconds_s:String = seconds < 10 ? "0" + seconds : seconds.toString();
			var minutes_s:String = minutes < 10 ? "0" + minutes : minutes.toString();
			var hours_s:String = hours < 10 ? "0" + hours : hours.toString();
			var year_s:String = year.toString();
			var month_s:String = month < 10 ? "0" + month : month.toString();
			var day_s:String = day < 10 ? "0" + day : day.toString();
			
						
			// concatenate the values and show them in the text field
			text_txt.text = hours_s + ":" + minutes_s + ":" + seconds_s;
			text_txt.appendText("\n");
			text_txt.appendText(year_s + "/" + month_s + "/" + day_s);
			
		}		
	}	
}

You can download all the files from here.