Flash Clock with the server's time using PHP - Page 3

ActionScript

First you load the variables output by the PHP script using the URLLoader Class and making sure you have the correct dataFormat: VARIABLES.
When the data finishes loading, you convert the variable seconds, which is a String, both to Number and to milliseconds, and store this value in a variable milliseconds.
After this you setup and ENTER_FRAME event to update the clock continuously. The elapsed time t1 is added to milliseconds so that you always have the correct number of milliseconds after 0:00:00 GMT January 1, 1970. You don't want to be left in the past!

The number of milliseconds - milliseconds - is passed to the Date Object.
From here you just have to grab the hours, minutes and seconds, as well as the year, month and day with the appropriate method, to display all this information.

Here's the code in MainServer.as:

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLLoader;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLRequest;
	import flash.text.TextField;
	import flash.utils.getTimer;
	
	public class MainServer extends Sprite 
	{
		
		public var text_txt:TextField;
		
		private var loader:URLLoader;
		private var t0:uint;
		private var milliseconds:Number;		
		
		
		public function MainServer():void 
		{
			// make sure the stage property exists
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}		
		/**
		 * load the data from the php script
		 * @param	e
		 */
		private function init(e:Event = null):void 
		{
			// make sure the text field has no text
			text_txt.text = "";
			
			// setup the loader
			loader = new URLLoader();
			// you're loading variable name/value pairs
			loader.dataFormat = URLLoaderDataFormat.VARIABLES;
			// when it finishes loading
			loader.addEventListener(Event.COMPLETE, loadComplete);
			
			// the request
			var request:URLRequest = new URLRequest();
			request.url = "server-time.php?ck=" + new Date().getTime();
			
			loader.load(request);
		}
		/**
		 * when the data finishes loading
		 * @param	e
		 */
		private function loadComplete(e:Event):void
		{
			// access the "seconds" variable
			var seconds:String = loader.data.seconds;
			
			// you want milliseconds, so lets multiply by 1000
			milliseconds = Number(seconds) * 1000;
			
			// the time when the data was received
			t0 = getTimer();
			
			// start a repetitive task
			addEventListener(Event.ENTER_FRAME, updateClock);
		}
		/**
		 * show the updated time and date
		 * @param	e
		 */
		private function updateClock(e:Event):void 
		{
			// time elapsed since t0
			var t1:uint = getTimer() - t0;
			// current time on the server: milliseconds + t1
			var myDate:Date = new Date(milliseconds + t1);
			
			// get the seconds, minutes and hours
			var seconds:uint = myDate.getSeconds();
			var minutes:uint = myDate.getMinutes();
			var hours:uint = myDate.getHours();
			
			// get the year, month and day
			var year:uint = myDate.getFullYear();
			var month:uint = myDate.getMonth() + 1;
			var day:uint = myDate.getDate();			
			
			
			// concatenate the values and show them in the text field
			text_txt.text = hours + ":" + minutes + ":" + seconds;
			text_txt.appendText("\n");
			text_txt.appendText(year + "/" + month + "/" + day);
		}		
	}	
}