Dynamic masking using the drawing API - Page 4

Movie 2: The pixelated fade-in effect

I'm sure you've all seen this in Powerpoint or Director but this nice effect is rarely seen in Flash: random pixels of an image appear successively until the entire image is shown. Although there are some difficulties associated with randomization, this effect is still simple enough to grasp conceptually that it may be shown here. Using a "maskee" movie clip as with the previous movie, you may add the following script to clip:

onClipEvent(load)
{
  numY = 26;
  numX = 120;
  numPerFrame = 12;
  currSquare = 0;
  choices = new Array();
  for(i = 0; i < numX*numY; i++)
  {
    choices.push(i);
  }
	
  _root.createEmptyMovieClip("mask", 0);
  this.setMask(_root.mask);
	
  function drawSquare(x,y)
  {
    with(_root.mask)
    {
      moveTo(x,y);
      beginFill(0x000088)
      lineTo(x+5,y);
      lineTo(x+5,y+5);
      lineTo(x,y+5);
      endFill();
    }
  }
}
onClipEvent(enterFrame)
{
  if(currSquare < numX*numY)
  {
    for(i = 0; i < numPerFrame; i++)
    {
      j = random(choices.length);
      t = choices[j];
      choices[j] = choices[choices.length - 1];
      choices.pop();
      x = t % numX;
      y = Math.floor( t / numX );
      drawSquare(x*5, y*5);
    }
    currSquare += numPerFrame;
    this._alpha = currSquare/(numX*numY)*100;
  }
}

Now if you test the movie you should get a nice pixelated fade in effect: 5x5 pixel squares successively appear randomly on the screen. Now I don't expect you to understand every detail of the preceding script but it should give you some hints on using dynamic masks to create fade-ins.

The main difficulty consists of randomly choosing the squares that will be drawn on a given turn. Squares are numbered from the top left. An array is created called choices which initially contains the numbers of all the squares. At some point in the enterFrame event, an element in the array is randomly picked and kept in memory. A switch is made with the last item in the array and the array is popped, meaning the last element is removed. Then this square is drawn on the screen.

As you see this script uses basically the same drawing routine as the previous one but in a different context. It uses the same trick as the first movie in creating the mask: as long as the clear function is not called, everything that is drawn in the target clip is kept in memory and all subsequent shapes add up. This gives us a nice fade-in effect.