Introduction to Papervision 3D and Flash - Page 7

Alternative method of adding the material.

In the previous method I drew a rectangle on the stage then dragged it off the side of the stage so that it couldn't be seen when we played the Flash Movie. A neater method would be to keep the rectangle material in the Library and access it with Actionscript. Here's how it's done.

Choose Insert - New Symbol from the main menu. Name the symbol Picture, ensure its type is Movie Clip and the registration point is in the top left corner. Check the Export for Actionscript checkbox and note that the class is automatically set to Picture.

Click OK and you will probably receive a warning that a definition for the class could not be found. Just click ok - Flash will automatically create the required definition. This creates a new class of object called Picture, which is a sub-class of the MovieClip object.

If objects, classes and things sound like gobbledygook to you, then don't worry - they are terminology used in Object Oriented Programming, but you don't need to understand this to complete the tutorial. If you really want to know more about this, try here - http://en.wikipedia.org/wiki/Object-oriented_programming

You should now see a blank stage where you can draw your material. For the time being just draw a coloured rectangle.

Go back to Scene 1 and select Frame 1. Open the Actions Panel and add the following line of code before the line that creates the material to create the necessary object.

var myPicture:Picture=new Picture();

Notice that this code is creating a new instance of a the class we just created called Picture.

Test your movie and you should see the symbol you created earlier rotating on the plane.

Here is a complete code listing at this stage.

import org.papervision3d.cameras.Camera3D;
import org.papervision3d.render.BasicRenderEngine;
import org.papervision3d.scenes.Scene3D;
import org.papervision3d.view.Viewport3D;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.materials.*;

var viewport:Viewport3D = new Viewport3D(stage.stageWidth,stage.stageHeight);
var scene:Scene3D = new Scene3D();
var camera:Camera3D = new Camera3D();
var renderer:BasicRenderEngine = new BasicRenderEngine();

var myPicture:Picture=new Picture();
var material:MovieMaterial = new MovieMaterial(myPicture);
material.oneSide = false;
var plane:Plane = new Plane(material,myPicture.width,myPicture.height);

addChild(viewport);
scene.addChild(plane);
renderer.renderScene(scene, camera, viewport);

addEventListener( Event.ENTER_FRAME, loop);

function loop(event:Event):void {
   plane.yaw(5);
   renderer.renderScene(scene, camera, viewport);
}

camera.z=-500;